да в том то и дело, сижу теперь кукую с фондами, хочу их в январе збагрить, да курсы не подходят,
если дольше держать, на что то надеятся, то можно будет очень на долго замороженым быть...
ведь праздник быков вечно длится не может...

А черт его знает. Может дальше пойдет, а может и пауза года так на 2-3. Я исхожу из последнего и в этом году почти все мои фонды пораспродавал. Начал с немецких в мае, потом Восточную Европу летом и закончил Индией на прошлой неделе. Оставил только 2 фонда: Global и европейский. Сижу теперь на Tagesgeld.

да я давно бы вс╦ это нахрен пораспродал бы, да по котракту раньше не имею право...
могу только в янворе...

ДАХ 27.12.07 в 7:00 достиг дочки 8160...
график дах от Futures DAX...
на Хетра конечно этого днём с огнём не найдёшь...
посмотрим, может это не большой слив перед праздниками был...
ничего нового пока...

Futures DAX... пробитие было, как подтверждение, хотя может ни чего и не дать...
не рас уже было, что нос высунит и назад...

Ради интереса запрограмировал сегодня стратегию, основанную на StochRSI индикаторе, описанную в декабрьском выпуске маркетиндекс магазине, и протестировал на DAXе за последнии 10 лет, дает очень даже неплохие результаты: больше 70% erfolgreiche Trades. Только всесто трендового фильтра я взял не MACD а AO индикатор. Намного лучше.
Если есть интерес, выложу сюда код

А там есть такая возможность системы тестировать?

А у меня чтото ничего не выда╦т этот индикатор -StochRSI- по DAXу

Серега, я на ProRealTime все тестирую. http://www.prorealtime.com/de/. Замельдуйся там, у них дневные данные бесплатно. Тестирование там Backtesting называется. Загоняешь свою стратегию и смотришь как она в прошлом работала. StochRSI у них нету, я сам написал. Вот код индикатора. Его там надо в раздел "Indikator" загонять, а там потом на "Indikator erstellen"
REM StochRSI nach Tushar Chande
Value1 = RSI[p](Close) - Lowest[p](RSI[p](Close))
Value2 = Highest[p](RSI[p](Close)) - Lowest[p](RSI[p](Close))
IF Value2 <> 0 THEN
Value3 = Value1 / Value2
ENDIF
stochrsi = ExponentialAverage[p](Value3)*100
RETURN stochrsi as "StochRSI"

А вот этот индикатор уже показывает точки входа и выхода по StochRSI стратегии
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// StochRSI Indikator
// p - Periode in Tagen ( 7 ist fuer DAX optimal )
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
p = 7
Value1 = RSI[p](Close) - Lowest[p](RSI[p](Close))
Value2 = Highest[p](RSI[p](Close)) - Lowest[p](RSI[p](Close))
IF Value2 <> 0 THEN
Value3 = Value1 / Value2
ENDIF
// StochRSI-Wert
storsi = ExponentialAverage[p](Value3)*100
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// Awesome Oscillator AO (wird fuer die Trend-Ermittlung benoetigt )
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
AO=Average[5](MedianPrice)-Average[34](MedianPrice)
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// M A I N
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// Regeln fuer den Long-Einstieg
// 1) AO > 0
// 2) StochRSI ist unter 40 gefallen und dreht sich nach oben
// 3) Man geht long zum Schlusskurs. Stoploss wird um 0,3% unter dem Tief vom Einstiegsbalken gesetzt
// 4) Drei mögliche Ausstiegsvarianten:
// a) Ausstieg nach 50 Punkten. Die Position wird komplett glattgestellt
// b) Stoploss wird gerissen
// c) StochRSI steigt ueber 70
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
golong = storsi[1] <= 40 and storsi > storsi[1] and storsi[1] < storsi[2] and AO > 0
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// Regeln fuer den Short-Einstieg
// 1) AO < 0
// 2) StochRSI ist ueber 70 gestiegen und dreht sich nach unten
// 3) Man geht short zum Schlusskurs. Stoploss wird um 0,3% ueber dem Hoch vom Einstiegsbalken gesetzt
// 4) Drei mögliche Ausstiegsvarianten:
// a) Ausstieg nach 50 Punkten. Die Position wird komlett glattgestellt
// b) Stoploss wird gerissen
// c) StochRSI faellt unter 30
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
goshort = storsi[1] >=70 and storsi < storsi[1] and storsi[1] > storsi[2] and AO < 0
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// Variablendeklaration
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// Ausstieg nach 50 Punkten
ausstieg = 50
enterlong = 0
entershort = 0
quitlong = 0
quitshort = 0
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// Long Einstieg
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
if golong and not belong then
enterlong = 1
stoplosslong = low * 0.997
belong = 1
buypricelong = close
endif
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// Long Ausstieg
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
if belong then
if storsi crosses over 70 or close - buypricelong >= ausstieg or high crosses under stoplosslong then
quitlong = -0.5
belong = 0
endif
endif
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// Short Einstieg
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
if goshort and not beshort then
entershort = -1
stoplossshort = high * 1.003
beshort = 1
buypriceshort = close
endif
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// Short Ausstieg
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
if beshort then
if storsi crosses under 30 or buypriceshort - close >= ausstieg or high crosses over stoplossshort then
quitshort = 0.5
beshort = 0
endif
endif
return enterlong as "GoLong", quitlong as "ExitLong", entershort as "GoShort", quitshort as "ExitShort"

Не Сань, ну не надо так пугать человека под новый год

Извини, пугать не хотел.

Вот у меня по МЕТРО был кое какой сигнал (спорный)
Я правде с неделю данные не актуализировал.

Сань, вот этот индекатор не заходит... ошибку пишет

вот большой индекатор заш╦л, но стрлочек и этих крестиков нету...
ты мне как то уже всю эту каляску показывал, но я зыбал

О, Вить, извини, забыл написать, что там еще параметр один загнать надо. Жми в индикаторе на кнопку "Hinzufügen" и заноси там данные как тут на картинке и потом на ОК

ОК... понял

Чтобы стрелки появились, тебе надо вот этот код загнать. Только не в индикаторы а в ProBackTest

//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// StochRSI Indikator
// p - Periode in Tagen ( 7 ist fuer DAX optimal )
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
p = 7
Value1 = RSI[p](Close) - Lowest[p](RSI[p](Close))
Value2 = Highest[p](RSI[p](Close)) - Lowest[p](RSI[p](Close))
IF Value2 <> 0 THEN
Value3 = Value1 / Value2
ENDIF
// StochRSI-Wert
storsi = ExponentialAverage[p](Value3)*100
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// Awesome Oscillator AO (wir fuer die Trend-Ermittlung benoetigt )
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
AO=Average[5](MedianPrice)-Average[34](MedianPrice)
// Regel long
regel1 = storsi[1] <= 40 and storsi > storsi[1] and storsi[1] < storsi[2] and AO > 0
// Regel short
regel2 = storsi[1] >=70 and storsi < storsi[1] and storsi[1] > storsi[2] and AO < 0
ausstieg = 50
if not longonmarket and regel1 then
buy 100%capital at market thisbaronclose
stoplosslong = low * 0.997
endif
if longonmarket then
if storsi crosses over 70 then
sell 100%capital at market thisbaronclose
elsif close - entryquote >= ausstieg then
sell 100%capital at market thisbaronclose
elsif high crosses under stoplosslong then
sell 100%capital at market thisbaronclose
endif
endif
if not shortonmarket and regel2 then
sellshort 100%capital at market thisbaronclose
stoplossshort = high * 1.003
endif
if shortonmarket then
if storsi crosses under 30 then
exitshort 100%capital at market thisbaronclose
elsif entryquote - close >= ausstieg then
exitshort 100%capital at market thisbaronclose
elsif high crosses over stoplossshort then
exitshort 100%capital at market thisbaronclose
endif
endif

Потом там в Backtest надо кое что в Kapitalverwaltung изменить. Вот на картинке розовым пометил

ОК... я понимэ
маленький индекатор уже дрин...
пробую его в СМС запихать, пока не получается...